ESP32 sensor dashboard#

  phone ──HTTPS──▶ greenhouse-byrne.a.tollan.app
                                 ▲
                                 │ the board connects out
  ESP32 ─────────────────────────┘
    your sketch answers each visit

lib_deps =
  tollan-agent
  adafruit/DHT sensor library@^1.4.6
  adafruit/Adafruit Unified Sensor@^1.1.14

// Greenhouse: an ESP32 + DHT22 serving a live page at its own HTTPS address.
#include <WiFi.h>
#include <DHT.h>
#include <TollanAgent.h>
#include "tollan_config.h"   // from the console's demo project
using namespace tollan;

static const char* WIFI_SSID = "your-wifi";
static const char* WIFI_PASS = "your-wifi-password";

DHT dht(2, DHT22);   // data pin on GPIO 2
TollanAgent agent;
float tempC = NAN, humidity = NAN;

static const char PAGE[] = R"HTML(<!doctype html>
<meta name="viewport" content="width=device-width,initial-scale=1">
<title>Greenhouse</title>
<style>body{font:20px system-ui;text-align:center;margin-top:20vh}b{font-size:3em}</style>
<p><b id="t">--</b> &deg;C<br><span id="h">--</span> % humidity</p>
<script>
async function tick() {
  const d = await (await fetch('/api')).json();
  t.textContent = d.tempC ?? '--';
  h.textContent = d.humidity ?? '--';
}
tick(); setInterval(tick, 5000);
</script>
)HTML";

// Send one complete HTTP response on a channel, then close it.
static void reply(uint32_t ch, const char* status, const char* type, const char* body, size_t len) {
  char head[160];
  int n = snprintf(head, sizeof(head),
                   "HTTP/1.1 %s\r\nContent-Type: %s\r\nContent-Length: %u\r\n"
                   "Connection: close\r\n\r\n",
                   status, type, (unsigned)len);
  agent.send(ch, (const uint8_t*)head, n);
  for (size_t off = 0; off < len; off += 1024) {   // send in 1 KB pieces
    agent.send(ch, (const uint8_t*)body + off, len - off < 1024 ? len - off : 1024);
  }
  agent.closeChannel(ch);
}

void setup() {
  Serial.begin(115200);
  dht.begin();

  WiFi.mode(WIFI_STA);
  WiFi.begin(WIFI_SSID, WIFI_PASS);
  while (WiFi.status() != WL_CONNECTED) delay(300);
  agent.log().printf("wifi ok, ip=%s\n", WiFi.localIP().toString().c_str());

  TollanConfig cfg;
  cfg.host = TOLLAN_RELAY_HOST;
  cfg.port = TOLLAN_RELAY_PORT;
  cfg.caCert = CA_CERT;
#ifdef TOLLAN_ENROLL_TOKEN
  cfg.enrollUrl = TOLLAN_ENROLL_URL;     // first boot: the board makes its key and enrolls
  cfg.enrollToken = TOLLAN_ENROLL_TOKEN;
  cfg.enrollCaCert = TOLLAN_ENROLL_CA;
#else
  cfg.clientCert = DEVICE_CERT;
  cfg.clientKey = DEVICE_KEY;
#endif
  cfg.renewUrl = TOLLAN_RENEW_URL;
  cfg.deviceId = TOLLAN_DEVICE_ID;       // health check-in for the console
  cfg.targetsUrl = TOLLAN_TARGETS_URL;

  // Every visit arrives here as an HTTP request. A GET fits in the first chunk, so we
  // answer on it; a server taking POST bodies would buffer until the headers end.
  agent.onData([](uint32_t ch, const uint8_t* data, size_t len) {
    const char* req = (const char*)data;
    if (len >= 8 && memcmp(req, "GET /api", 8) == 0) {
      char json[64];
      int n = isnan(tempC)
                  ? snprintf(json, sizeof(json), "{\"tempC\":null,\"humidity\":null}")
                  : snprintf(json, sizeof(json), "{\"tempC\":%.1f,\"humidity\":%.0f}", tempC, humidity);
      reply(ch, "200 OK", "application/json", json, n);
    } else if (len >= 6 && memcmp(req, "GET / ", 6) == 0) {
      reply(ch, "200 OK", "text/html; charset=utf-8", PAGE, sizeof(PAGE) - 1);
    } else {
      reply(ch, "404 Not Found", "text/plain", "not found\n", 10);
    }
  });

  agent.begin(cfg);
}

void loop() {
  agent.loop();

  // The DHT22 needs 2 s between reads. Never delay() here: loop() must keep
  // calling agent.loop() or the board drops off.
  static uint32_t lastRead = 0;
  if (millis() - lastRead >= 2000) {
    lastRead = millis();
    float t = dht.readTemperature(), h = dht.readHumidity();
    if (isnan(t) || isnan(h)) {
      agent.log().println("DHT22 read failed: check the wiring and pull-up");
    } else {
      tempC = t;
      humidity = h;
    }
  }
  delay(2);
}

curl https://greenhouse-byrne.a.tollan.app/api
{"tempC":21.4,"humidity":56}